DCL SPCPTR .THE-STACK;
DCL DD      THE-STACK CHAR(6416) BDRY(16);
    DCL DD  STK-BYTES-PRV      BIN(4) DEF(THE-STACK) POS( 1);
    DCL DD  STK-BYTES-AVL      BIN(4) DEF(THE-STACK) POS( 5);
    DCL DD  STK-NBR-OF-ENTRIES BIN(4) DEF(THE-STACK) POS( 9);
    DCL DD  *                  BIN(4) DEF(THE-STACK) POS(13);
    DCL DD  STK-ENTRY(50)   CHAR(128) DEF(THE-STACK) POS(17);

DCL DD THE-ENTRY CHAR(128) BDRY(16);
    DCL SYSPTR .THE-ENTRY-PGM DEF(THE-ENTRY) POS(33);

DCL DD PGM-NBR BIN(4);

DCL SPCPTR .PTR-TEMPLATE INIT(PTR-TEMPLATE);
DCL DD      PTR-TEMPLATE CHAR(76);
    DCL DD  PTR-PROVIDED        BIN(4) DEF(PTR-TEMPLATE) POS( 1);
    DCL DD  PTR-RETURNED        BIN(4) DEF(PTR-TEMPLATE) POS( 5);
    DCL DD  PTR-TYPE           CHAR(1) DEF(PTR-TEMPLATE) POS( 9);
    DCL DD  PTR-DATA          CHAR(68) DEF(PTR-TEMPLATE) POS(10);
        DCL DD PTR-CTX-TYPE   CHAR( 2) DEF(PTR-DATA)     POS ( 1);
        DCL DD PTR-CTX-NAME   CHAR(30) DEF(PTR-DATA)     POS ( 3);
        DCL DD PTR-OBJ-TYPE   CHAR( 2) DEF(PTR-DATA)     POS (33);
        DCL DD PTR-OBJ-NAME   CHAR(30) DEF(PTR-DATA)     POS (35);
        DCL DD PTR-...        CHAR( 4) DEF(PTR-DATA)     POS (65);

DCL EXCM * EXCID(H'4401') BP(NEXT-PROGRAM) CV("MCH") IMD;
/*              MCH6801                                            */
/*******************************************************************/

GET-STACK:
    CPYNV      STK-BYTES-PRV, 6416;
    SETSPP    .THE-STACK, THE-STACK;
    MATINVS   .THE-STACK, *; /* YOUR OWN JOB */

    CPYNV      PGM-NBR, 0;
NEXT-PROGRAM:
    ADDN(S)    PGM-NBR, 1;
    CMPNV(B)   PGM-NBR, STK-NBR-OF-ENTRIES/HI(DONE);
    CPYBWP     THE-ENTRY, STK-ENTRY(PGM-NBR);

    CPYNV      PTR-PROVIDED, 76;
    MATPTR    .PTR-TEMPLATE, .THE-ENTRY-PGM;

    CPYBREP    MSG-TEXT, " ";
    CVTHC      MSG-TEXT(1:32), THE-ENTRY(33:16);

    CPYBLAP    MSG-TEXT(34:11), PTR-CTX-NAME, " ";
    CPYBLAP    MSG-TEXT(46:11), PTR-OBJ-NAME, " ";
    CALLI      SHOW-MESSAGE, *, .SHOW-MESSAGE;
    B          NEXT-PROGRAM;

DONE:
    RTX        *;

%INCLUDE SHOWMSG